Camping Kitchen Box

Kitchen Box

I have been using a cheap rubbermaid box for all of my main cooking gear. I do have a couple of small ammo cans for the smaller items that fit in my bed platform drawers, but for the big items, it is the rubbermaid. About a year ago I picked up a cheap Nanuk 960 case (about the same size as a Pelican 1610, but from another company). It turns out that this case is a really good size for a kitchen box, so, I figured I could do something with it.

Pelican has this organization thing called the TrekPak system, but it is super expensive, and it really isn't as rigid as I would like for my kitchen box, so I went about modeling up brackets that I could print on my 3d printer, and use some extra plastic sheets I have laying around.

The end result:


The internal structure is made of PETG printed brackets attached to acrylic plastic sheets, held together by M3 nuts and bolts. The acrylic sheets just happen to be what I had on hand (they were purchased for very little, so cost was kept down).


I used some extra mini-cell foam I had laying around along with some padding I purchased from some costume shop online to pad out the outside of the structure. I was in the process of padding out the internal compartments when I lost motivation and stopped. It is a kitchen box, these pots and pans don't really need internal padding.


I ended up printing up a bracket to hold the cutting board in place so it won't bang around in my 'open' compartment that is going to hold all of the miscellaneous items I still have to pack (propane tanks for the stove, spatula, etc).


Mostly put together with the core items I want to carry with me


This kitchen box carries:

• 2 burner stove (grey box)
• 1 large skillet (commercial skillet bought used from a restaurant going out of business sale)
• 2 small skillets (commercial skillets bought at the same sale as the big one)
• MSR pots (camping pots that I have had for ages)
• 8" Lodge dutch oven
• 2x10" enameled plates
• 1 cutting board (9"x10" cut to size to fit in the space)
• 6.5" Santoku knife
• 3.5" paring knife
• other small things

When all is said and done, the box is pretty heavy, but it does have wheels and some beefy handles. It can also be tied down when traveling.

Is it overkill? Yup.

Do I have any regrets right now? Nope.

 

Pelican (and not Pelican) brackets

For the kitchen box, I ended up 3d printing lots of T-brackets and corner brackets to hold together the various walls I put together. Here are the models I used.

Corner Top:


Corner long:


Code (openSCAD) for the corner brackets:

Code:

$fn=100;

cornerRadius = 40;
cornerZ = 140;
bracketLength = 20;
bracketThickness = 16;

wallThickness = 3.5;
wallZoffset = 0;
wallYoffset = -4;

boltHeadHeight = 3.2;
boltHeadDiameter = 5.7;
boltLength = bracketThickness-boltHeadHeight;
boltDiameter = 3.2;

nutHeight = 2.7;
nutDiameter = 6.4;

//corner cut, only on some pelican cases. this should be optional
cornerCutoutRadius = 8;
cornerCutoutZ = 50.5;
cornerCutoutOffSet = 1.5;

module bolt(){
  // bolt head
  cylinder(boltHeadHeight+.1,boltHeadDiameter/2,boltHeadDiameter/2);
  translate([0,0,-boltLength-.2]){cylinder(boltLength+.2,boltDiameter/2,boltDiameter/2);}
  //nut on other end
  translate([0,0,-boltLength-.2]){nut();}
}

module nut(){
  $fn=6;
  cylinder(nutHeight+.1,nutDiameter/2,nutDiameter/2);

}

module drawBolts(offsetXY,offsetZ){
  translate([(cornerRadius/2)-boltHeadHeight+.1,offsetXY,offsetZ]){rotate([0,90,0]){bolt();}}
  translate([-offsetXY,-(cornerRadius/2)+boltHeadHeight-.1,offsetZ]){rotate([90,90,0]){bolt();}}
}

module wallCutout1(){
  cube([wallThickness,bracketLength+20,cornerZ+1]);
}

module wallCutout2(){
  cube([bracketLength+20,wallThickness,cornerZ+1]);
}

//rounded part of corner
module cornerPart(){
  cylinder(cornerZ,cornerRadius/2,cornerRadius/2);
  translate([(cornerRadius/2)-(bracketThickness),0,0]){cube([bracketThickness,bracketLength,cornerZ]);}
  translate([-bracketLength,-((cornerRadius/2)),0]){cube([bracketLength,bracketThickness,cornerZ]);}
}

module cutOutPart(){
  translate([(cornerRadius/2)-(bracketThickness),-((cornerRadius/2))+bracketThickness,0]){
  rotate([0,0,90]){
  cube([1000,100,cornerZ]);
  }
  }
  //right side (remove any curve)
  translate([0,bracketLength,0]){cube([100,100,cornerZ]);}

  //top side (remove any curve)
  translate([-bracketLength,-bracketLength-40,0]){rotate([0,0,90]){cube([100,100,cornerZ]);}}

}

module cornerCutout(){
  //translate([cornerRadius/3+cornerCutoutRadius*2,-cornerRadius/3+cornerCutoutRadius*2,0]){cylinder(cornerCutoutZ,cornerCutoutRadius/2,cornerCutoutRadius/2);}
  translate([cornerRadius/3+cornerCutoutRadius/3-cornerCutoutOffSet,-cornerRadius/3-cornerCutoutRadius/3+cornerCutoutOffSet,0]){cylinder(cornerCutoutZ,cornerCutoutRadius/2,cornerCutoutRadius/2);}
}


difference(){
  cornerPart();
  //optional cutout in corner (for pelican 1400)
  //cornerCutout();
  //wall cutout
  translate([(cornerRadius/2)-bracketThickness/2-wallThickness/2,wallYoffset,wallZoffset]){wallCutout1();}
  translate([-bracketLength-wallYoffset-20,-((cornerRadius/2))+bracketThickness/2-wallThickness/2,wallZoffset]){wallCutout2();}   
  //bolt1
  drawBolts(10,cornerZ*1/8);
  //drawBolts(10,cornerZ*2/8);
  //drawBolts(10,cornerZ*3/8);
  drawBolts(10,cornerZ*4/8);
  //drawBolts(10,cornerZ*5/8);
  //drawBolts(10,cornerZ*6/8);
  drawBolts(10,cornerZ*7/8);

  //drawBolts(10,30);
  //drawBolts(10,60);
  //drawBolts(10,75);
  //drawBolts(10,90);
  //drawBolts(10,105);

  cutOutPart();
   
  //cornerCutout();
}

T-Bracket top:


T-Bracket long:


Code (openSCAD) for T-Brackets:

Code:

$fn=100;

bracketLength = 23;
bracketThickness = 12;
bracketZ = 165;

wallThickness = 3.5;
wallZoffset = 0;
wallYoffset = 0;

boltHeadHeight = 3.2;
boltHeadDiameter = 5.7;
boltLength = bracketThickness-boltHeadHeight;
boltDiameter = 3.2;

nutHeight = 2.7;
nutDiameter = 6.4;

//corner cut, only on some pelican cases. this should be optional
cornerCutoutRadius = 4;
cornerCutoutZ = 24;


module bolt(){
  // bolt head
  cylinder(boltHeadHeight+.1,boltHeadDiameter/2,boltHeadDiameter/2);
  translate([0,0,-boltLength-.2]){cylinder(boltLength+.2,boltDiameter/2,boltDiameter/2);}
  //nut on other end
  translate([0,0,-boltLength-.2]){nut();}
}

module nut(){
  $fn=6;
  cylinder(nutHeight+.1,nutDiameter/2,nutDiameter/2);
}

module drawBolts(offsetXY,offsetZ){
  // right
  translate([offsetXY,-bracketThickness/2+boltHeadHeight,offsetZ]){rotate([90,90,0]){bolt();}}
  // left
  translate([-offsetXY,-bracketThickness/2+boltHeadHeight,offsetZ]){rotate([90,90,0]){bolt();}}


  // top
  translate([bracketThickness/2-boltHeadHeight,offsetXY,offsetZ]){rotate([0,90,0]){bolt();}}

}

module mainBracket(){
  // right
  translate([0,-bracketThickness/2,0]){cube([bracketLength,bracketThickness,bracketZ]);}
  // left
  translate([-bracketLength,-bracketThickness/2,0]){cube([bracketLength,bracketThickness,bracketZ]);}
  // top
  translate([bracketThickness/2,0,0]){rotate([0,0,90]){cube([bracketLength,bracketThickness,bracketZ]);}}
}

module wallCutout(){
  cube([bracketLength,wallThickness,bracketZ+1]);
}


difference(){
  mainBracket();
  // right wall
  translate([wallYoffset,-wallThickness/2,wallZoffset]){wallCutout();}   
  // left wall
  translate([-bracketLength-wallYoffset,-wallThickness/2,wallZoffset]){wallCutout();}   
  // top wall cutout
  translate([wallThickness/2,wallYoffset,wallZoffset]){rotate([0,0,90]){wallCutout();}}   
  // bolt 1
  //drawBolts(15,15);
  drawBolts(15,bracketZ*1/8);
  //drawBolts(15,bracketZ*2/8);
  //drawBolts(15,bracketZ*3/8);
  drawBolts(15,bracketZ*4/8);
  //drawBolts(15,v*5/8);
  //drawBolts(15,bracketZ*6/8);
  drawBolts(15,bracketZ*7/8);

  //cut out so only parts show
  //translate([-100,0,0]){cube([200,200,200]);} //for backplate only

  //translate([-100,-200,0]){cube([200,200,200]);} //for side 1 and 2, cut off backplate
  //translate([-200,0,0]){cube([200,200,200]);} //for side 1   
  //translate([0,0,0]){cube([200,200,200]);} //for side 2   

}

 

Cool. Make sure that your enameled plates don't rattle together or the finish can wear or chip (wanna guess how I found that out? ). I just put a paper towel between mine and it seems to work.